话说2018年春节的时候，3d打印了一个机械臂。

还是老样子，在纸上先画一个机械臂大概的形状

在CAD中画出具体参数，看看用什么养的配置比较合适，作业半径会是多少。 

确定参数就可以开始做三维建模。

一步一步开始搭建机械臂的每个部分。

底座

第一关节

第二关节

第三关节，上面可以安装夹具

所有的配件就是这些

机械手臂上当然是要有手了 XD

用机械手来帮你选一瓶饮料

还是再切一个合适的手给机械臂

当然机械臂也可以很欢乐

7,011 total views, 2 views today

The post 3D打印机械臂 appeared first on HE Qichen's Hackspace.

为了造一套门禁系统，淘宝上搞来了一套RFID读卡器。

RC522，看上去是比较多的型号，哪家店都买得到。

本来想拔整个模块装进一个接线盒里，但是这尺寸刚刚好，如果放进去就没法盖盖子了。。。无奈，先裸奔。

Youtube连接：https://www.youtube.com/watch?v=4yIT7Gunn6c

也是网上找来的代码

 

#include <SPI.h>

#define uchar unsigned char
#define uint unsigned int

//data array maxium length
#define MAX_LEN 16

/////////////////////////////////////////////////////////////////////
//set the pin
/////////////////////////////////////////////////////////////////////
const int chipSelectPin = 10;
const int NRSTPD = 5;

 

//MF522 command bits
#define PCD_IDLE 0x00 //NO action; cancel current commands
#define PCD_AUTHENT 0x0E //verify password key
#define PCD_RECEIVE 0x08 //receive data
#define PCD_TRANSMIT 0x04 //send data
#define PCD_TRANSCEIVE 0x0C //send and receive data
#define PCD_RESETPHASE 0x0F //reset
#define PCD_CALCCRC 0x03 //CRC check and caculation

//Mifare_One card command bits
#define PICC_REQIDL 0x26 //Search the cards that not into sleep mode in the antenna area
#define PICC_REQALL 0x52 //Search all the cards in the antenna area
#define PICC_ANTICOLL 0x93 //prevent conflict
#define PICC_SElECTTAG 0x93 //select card
#define PICC_AUTHENT1A 0x60 //verify A password key
#define PICC_AUTHENT1B 0x61 //verify B password key
#define PICC_READ 0x30 //read
#define PICC_WRITE 0xA0 //write
#define PICC_DECREMENT 0xC0 //deduct value
#define PICC_INCREMENT 0xC1 //charge up value
#define PICC_RESTORE 0xC2 //Restore data into buffer
#define PICC_TRANSFER 0xB0 //Save data into buffer
#define PICC_HALT 0x50 //sleep mode
//THe mistake code that return when communicate with MF522
#define MI_OK 0
#define MI_NOTAGERR 1
#define MI_ERR 2
//------------------MFRC522 register ---------------
//Page 0:Command and Status
#define Reserved00 0x00
#define CommandReg 0x01
#define CommIEnReg 0x02
#define DivlEnReg 0x03
#define CommIrqReg 0x04
#define DivIrqReg 0x05
#define ErrorReg 0x06
#define Status1Reg 0x07
#define Status2Reg 0x08
#define FIFODataReg 0x09
#define FIFOLevelReg 0x0A
#define WaterLevelReg 0x0B
#define ControlReg 0x0C
#define BitFramingReg 0x0D
#define CollReg 0x0E
#define Reserved01 0x0F
//Page 1:Command
#define Reserved10 0x10
#define ModeReg 0x11
#define TxModeReg 0x12
#define RxModeReg 0x13
#define TxControlReg 0x14
#define TxAutoReg 0x15
#define TxSelReg 0x16
#define RxSelReg 0x17
#define RxThresholdReg 0x18
#define DemodReg 0x19
#define Reserved11 0x1A
#define Reserved12 0x1B
#define MifareReg 0x1C
#define Reserved13 0x1D
#define Reserved14 0x1E
#define SerialSpeedReg 0x1F
//Page 2:CFG
#define Reserved20 0x20
#define CRCResultRegM 0x21
#define CRCResultRegL 0x22
#define Reserved21 0x23
#define ModWidthReg 0x24
#define Reserved22 0x25
#define RFCfgReg 0x26
#define GsNReg 0x27
#define CWGsPReg 0x28
#define ModGsPReg 0x29
#define TModeReg 0x2A
#define TPrescalerReg 0x2B
#define TReloadRegH 0x2C
#define TReloadRegL 0x2D
#define TCounterValueRegH 0x2E
#define TCounterValueRegL 0x2F
//Page 3:TestRegister
#define Reserved30 0x30
#define TestSel1Reg 0x31
#define TestSel2Reg 0x32
#define TestPinEnReg 0x33
#define TestPinValueReg 0x34
#define TestBusReg 0x35
#define AutoTestReg 0x36
#define VersionReg 0x37
#define AnalogTestReg 0x38
#define TestDAC1Reg 0x39
#define TestDAC2Reg 0x3A
#define TestADCReg 0x3B
#define Reserved31 0x3C
#define Reserved32 0x3D
#define Reserved33 0x3E
#define Reserved34 0x3F
//-----------------------------------------------

//4 bytes Serial number of card, the 5 bytes is verfiy bytes
uchar serNum[5];

int AUTHED_ID_NUM = 8;

unsigned char AUTHED_ID_LIST[][4] =
{
{0x72, 0xBB, 0x7C, 0x6F},
{0xF1, 0x6D, 0xB3, 0x85},
{0x09, 0x11, 0x8F, 0x87},
{0xCF, 0x9C, 0x24, 0x71},
{0x88, 0x04, 0xBF, 0xC5},
{0x88, 0x04, 0x5D, 0x9E},
{0x88, 0x04, 0xF6, 0x8A},
{0x88, 0x99, 0xA5, 0xCA}
};

char *AUTHED_NAME_LIST[] =
{
"key-chain",
"white-card",
"Shanghai-transport",
"Beijing-transport",
"Guangzhou-Metro",
"Shenzhen-Metro",
"train-ticket #1",
"train-ticket #2"
};

 

void setup()
{
Serial.begin(57600);

SPI.begin();

pinMode(chipSelectPin,OUTPUT); // Set digital pin 10 as OUTPUT to connect it to the RFID /ENABLE pin
digitalWrite(chipSelectPin, LOW); // Activate the RFID reader
pinMode(NRSTPD,OUTPUT); // Set digital pin 5 , Not Reset and Power-down

MFRC522_Init();

pinMode(4, OUTPUT);
digitalWrite(4, LOW);
}

void showCardDetail()
{

uchar status;
uchar str[MAX_LEN];
// Show card type
ShowCardType(str);

//Prevent conflict, return the 4 bytes Serial number of the card
status = MFRC522_Anticoll(str);

// str[0..3]: serial number of the card
// str[4]: XOR checksum of the SN.
if (status == MI_OK)
{
Serial.print("The card's number is: ");
memcpy(serNum, str, 5);
ShowCardID(serNum);

// Check people associated with card ID
uchar* id = serNum;
if( id[0]==0x4B && id[1]==0xE6 && id[2]==0xD1 && id[3]==0x3B ) {
Serial.println("Hello Mary!");
} else if(id[0]==0x3B && id[1]==0xE6 && id[2]==0xD1 && id[3]==0x3B) {
Serial.println("Hello Greg!");
}else{
Serial.println("Hello unkown guy!");
}
}

}

unsigned long lastFoundTime = 0;
int lastFoundCard = -1;

void loop()
{

uchar status;
uchar str[MAX_LEN];
// Search card, return card types
status = MFRC522_Request(PICC_REQIDL, str);
if (status != MI_OK)
{
return;
}

//showCardDetail();
status = MFRC522_Anticoll(str);
if (status == MI_OK)
{
memcpy(serNum, str, 5);
uchar* id = serNum;
int authedId = findInAuthedList(id);
if (authedId >= 0)
{
if (lastFoundCard != authedId || (millis() - lastFoundTime) > 2000)
{
Serial.print("Card read: ");
Serial.println(AUTHED_NAME_LIST[authedId]);
lastFoundTime = millis();
digitalWrite(4, HIGH);
delay(50);
digitalWrite(4, LOW);
}

}
else
{
Serial.print("unknown card found: ");
ShowCardID(serNum);
}
lastFoundCard = authedId;
}

MFRC522_Halt(); //command the card into sleep mode

delay(200);
}

int findInAuthedList(uchar *id)
{
int i;
int j;
for (i=0; i<AUTHED_ID_NUM; ++i)
{
for (j=0; j<4; ++j)
{
if (AUTHED_ID_LIST[i][j] != id[j])
{
break;
}
}
if(j >= 4)
{
return i;
}
}
return -1;
}

/*
* Function：ShowCardID
* Description：Show Card ID
* Input parameter：ID string
* Return：Null
*/
void ShowCardID(uchar *id)
{
int IDlen=4;
for(int i=0; i<IDlen; i++){
Serial.print(0x0F & (id[i]>>4), HEX);
Serial.print(0x0F & id[i],HEX);
}
Serial.println("");
}

/*
* Function：ShowCardType
* Description：Show Card type
* Input parameter：Type string
* Return：Null
*/
void ShowCardType(uchar* type)
{
Serial.print("Card type: ");
if(type[0]==0x04&&type[1]==0x00)
Serial.println("MFOne-S50");
else if(type[0]==0x02&&type[1]==0x00)
Serial.println("MFOne-S70");
else if(type[0]==0x44&&type[1]==0x00)
Serial.println("MF-UltraLight");
else if(type[0]==0x08&&type[1]==0x00)
Serial.println("MF-Pro");
else if(type[0]==0x44&&type[1]==0x03)
Serial.println("MF Desire");
else
Serial.println("Unknown");
}

/*
* Function：Write_MFRC5200
* Description：write a byte data into one register of MR RC522
* Input parameter：addr--register address；val--the value that need to write in
* Return：Null
*/
void Write_MFRC522(uchar addr, uchar val)
{
digitalWrite(chipSelectPin, LOW);

//address format：0XXXXXX0
SPI.transfer((addr<<1)&0x7E);
SPI.transfer(val);

digitalWrite(chipSelectPin, HIGH);
}
/*
* Function：Read_MFRC522
* Description：read a byte data into one register of MR RC522
* Input parameter：addr--register address
* Return：return the read value
*/
uchar Read_MFRC522(uchar addr)
{
uchar val;

digitalWrite(chipSelectPin, LOW);

//address format：1XXXXXX0
SPI.transfer(((addr<<1)&0x7E) | 0x80);
val =SPI.transfer(0x00);

digitalWrite(chipSelectPin, HIGH);

return val;
}

/*
* Function：SetBitMask
* Description：set RC522 register bit
* Input parameter：reg--register address;mask--value
* Return：null
*/
void SetBitMask(uchar reg, uchar mask)
{
uchar tmp;
tmp = Read_MFRC522(reg);
Write_MFRC522(reg, tmp | mask); // set bit mask
}
/*
* Function：ClearBitMask
* Description：clear RC522 register bit
* Input parameter：reg--register address;mask--value
* Return：null
*/
void ClearBitMask(uchar reg, uchar mask)
{
uchar tmp;
tmp = Read_MFRC522(reg);
Write_MFRC522(reg, tmp & (~mask)); // clear bit mask
}
/*
* Function：AntennaOn
* Description：Turn on antenna, every time turn on or shut down antenna need at least 1ms delay
* Input parameter：null
* Return：null
*/
void AntennaOn(void)
{
uchar temp;

temp = Read_MFRC522(TxControlReg);
if (!(temp & 0x03))
{
SetBitMask(TxControlReg, 0x03);
}
}
/*
* Function：AntennaOff
* Description：Turn off antenna, every time turn on or shut down antenna need at least 1ms delay
* Input parameter：null
* Return：null
*/
void AntennaOff(void)
{
ClearBitMask(TxControlReg, 0x03);
}
/*
* Function：ResetMFRC522
* Description： reset RC522
* Input parameter：null
* Return：null
*/
void MFRC522_Reset(void)
{
Write_MFRC522(CommandReg, PCD_RESETPHASE);
}
/*
* Function：InitMFRC522
* Description：initilize RC522
* Input parameter：null
* Return：null
*/
void MFRC522_Init(void)
{
digitalWrite(NRSTPD,HIGH);

MFRC522_Reset();

//Timer: TPrescaler*TreloadVal/6.78MHz = 24ms
Write_MFRC522(TModeReg, 0x8D); //Tauto=1; f(Timer) = 6.78MHz/TPreScaler
Write_MFRC522(TPrescalerReg, 0x3E); //TModeReg[3..0] + TPrescalerReg
Write_MFRC522(TReloadRegL, 30);
Write_MFRC522(TReloadRegH, 0);

Write_MFRC522(TxAutoReg, 0x40); //100%ASK
Write_MFRC522(ModeReg, 0x3D); //CRC initilizate value 0x6363 ???

//ClearBitMask(Status2Reg, 0x08); //MFCrypto1On=0
//Write_MFRC522(RxSelReg, 0x86); //RxWait = RxSelReg[5..0]
//Write_MFRC522(RFCfgReg, 0x7F); //RxGain = 48dB

AntennaOn(); //turn on antenna
}
/*
* Function：MFRC522_Request
* Description：Searching card, read card type
* Input parameter：reqMode--search methods，
* TagType--return card types
* 0x4400 = Mifare_UltraLight
* 0x0400 = Mifare_One(S50)
* 0x0200 = Mifare_One(S70)
* 0x0800 = Mifare_Pro(X)
* 0x4403 = Mifare_DESFire
* return：return MI_OK if successed
*/
uchar MFRC522_Request(uchar reqMode, uchar *TagType)
{
uchar status;
uint backBits; //the data bits that received

Write_MFRC522(BitFramingReg, 0x07); //TxLastBists = BitFramingReg[2..0] ???

TagType[0] = reqMode;
status = MFRC522_ToCard(PCD_TRANSCEIVE, TagType, 1, TagType, &backBits);

if ((status != MI_OK) || (backBits != 0x10))
{
status = MI_ERR;
}

return status;
}
/*
* Function：MFRC522_ToCard
* Description：communicate between RC522 and ISO14443
* Input parameter：command--MF522 command bits
* sendData--send data to card via rc522
* sendLen--send data length
* backData--the return data from card
* backLen--the length of return data
* return：return MI_OK if successed
*/
uchar MFRC522_ToCard(uchar command, uchar *sendData, uchar sendLen, uchar *backData, uint *backLen)
{
uchar status = MI_ERR;
uchar irqEn = 0x00;
uchar waitIRq = 0x00;
uchar lastBits;
uchar n;
uint i;

switch (command)
{
case PCD_AUTHENT: //verify card password
{
irqEn = 0x12;
waitIRq = 0x10;
break;
}
case PCD_TRANSCEIVE: //send data in the FIFO
{
irqEn = 0x77;
waitIRq = 0x30;
break;
}
default:
break;
}

Write_MFRC522(CommIEnReg, irqEn|0x80); //Allow interruption
ClearBitMask(CommIrqReg, 0x80); //Clear all the interrupt bits
SetBitMask(FIFOLevelReg, 0x80); //FlushBuffer=1, FIFO initilizate

Write_MFRC522(CommandReg, PCD_IDLE); //NO action;cancel current command ???

//write data into FIFO
for (i=0; i<sendLen; i++)
{
Write_MFRC522(FIFODataReg, sendData[i]);
}

//procceed it
Write_MFRC522(CommandReg, command);
if (command == PCD_TRANSCEIVE)
{
SetBitMask(BitFramingReg, 0x80); //StartSend=1,transmission of data starts
}

//waite receive data is finished
i = 2000; //i should adjust according the clock, the maxium the waiting time should be 25 ms???
do
{
//CommIrqReg[7..0]
//Set1 TxIRq RxIRq IdleIRq HiAlerIRq LoAlertIRq ErrIRq TimerIRq
n = Read_MFRC522(CommIrqReg);
i--;
}
while ((i!=0) && !(n&0x01) && !(n&waitIRq));

ClearBitMask(BitFramingReg, 0x80); //StartSend=0

if (i != 0)
{
if(!(Read_MFRC522(ErrorReg) & 0x1B)) //BufferOvfl Collerr CRCErr ProtecolErr
{
status = MI_OK;
if (n & irqEn & 0x01)
{
status = MI_NOTAGERR; //??
}

if (command == PCD_TRANSCEIVE)
{
n = Read_MFRC522(FIFOLevelReg);
lastBits = Read_MFRC522(ControlReg) & 0x07;
if (lastBits)
{
*backLen = (n-1)*8 + lastBits;
}
else
{
*backLen = n*8;
}

if (n == 0)
{
n = 1;
}
if (n > MAX_LEN)
{
n = MAX_LEN;
}

//read the data from FIFO
for (i=0; i<n; i++)
{
backData[i] = Read_MFRC522(FIFODataReg);
}
}
}
else
{
status = MI_ERR;
}

}

//SetBitMask(ControlReg,0x80); //timer stops
//Write_MFRC522(CommandReg, PCD_IDLE);

return status;
}
/*
* Function：MFRC522_Anticoll
* Description：Prevent conflict, read the card serial number
* Input parameter：serNum--return the 4 bytes card serial number, the 5th byte is recheck byte
* return：return MI_OK if successed
*/
uchar MFRC522_Anticoll(uchar *serNum)
{
uchar status;
uchar i;
uchar serNumCheck=0;
uint unLen;

//ClearBitMask(Status2Reg, 0x08); //strSensclear
//ClearBitMask(CollReg,0x80); //ValuesAfterColl
Write_MFRC522(BitFramingReg, 0x00); //TxLastBists = BitFramingReg[2..0]

serNum[0] = PICC_ANTICOLL;
serNum[1] = 0x20;
status = MFRC522_ToCard(PCD_TRANSCEIVE, serNum, 2, serNum, &unLen);

if (status == MI_OK)
{
//Verify card serial number
for (i=0; i<4; i++)
{
serNumCheck ^= serNum[i];
}
if (serNumCheck != serNum[i])
{
status = MI_ERR;
}
}

//SetBitMask(CollReg, 0x80); //ValuesAfterColl=1

return status;
}
/*
* Function：CalulateCRC
* Description：Use MF522 to caculate CRC
* Input parameter：pIndata--the CRC data need to be read，len--data length，pOutData-- the caculated result of CRC
* return：Null
*/
void CalulateCRC(uchar *pIndata, uchar len, uchar *pOutData)
{
uchar i, n;

ClearBitMask(DivIrqReg, 0x04); //CRCIrq = 0
SetBitMask(FIFOLevelReg, 0x80); //Clear FIFO pointer
//Write_MFRC522(CommandReg, PCD_IDLE);

//Write data into FIFO
for (i=0; i<len; i++)
{
Write_MFRC522(FIFODataReg, *(pIndata+i));
}
Write_MFRC522(CommandReg, PCD_CALCCRC);

//waite CRC caculation to finish
i = 0xFF;
do
{
n = Read_MFRC522(DivIrqReg);
i--;
}
while ((i!=0) && !(n&0x04)); //CRCIrq = 1

//read CRC caculation result
pOutData[0] = Read_MFRC522(CRCResultRegL);
pOutData[1] = Read_MFRC522(CRCResultRegM);
}

 

/*
* Function：MFRC522_Write
* Description：write block data
* Input parameters：blockAddr--block address;writeData--Write 16 bytes data into block
* return：return MI_OK if successed
*/
uchar MFRC522_Write(uchar blockAddr, uchar *writeData)
{
uchar status;
uint recvBits;
uchar i;
uchar buff[18];

buff[0] = PICC_WRITE;
buff[1] = blockAddr;
CalulateCRC(buff, 2, &buff[2]);
status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 4, buff, &recvBits);

if ((status != MI_OK) || (recvBits != 4) || ((buff[0] & 0x0F) != 0x0A))
{
status = MI_ERR;
}

if (status == MI_OK)
{
for (i=0; i<16; i++) //Write 16 bytes data into FIFO
{
buff[i] = *(writeData+i);
}
CalulateCRC(buff, 16, &buff[16]);
status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 18, buff, &recvBits);

if ((status != MI_OK) || (recvBits != 4) || ((buff[0] & 0x0F) != 0x0A))
{
status = MI_ERR;
}
}

return status;
}
/*
* Function：MFRC522_Halt
* Description：Command the cards into sleep mode
* Input parameters：null
* return：null
*/
void MFRC522_Halt(void)
{
uchar status;
uint unLen;
uchar buff[4];

buff[0] = PICC_HALT;
buff[1] = 0;
CalulateCRC(buff, 2, &buff[2]);

status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 4, buff,&unLen);
}

6,633 total views, no views today

The post RC522读RFID卡 appeared first on HE Qichen's Hackspace.

点击下载后，出现了这个问题
avrdude: stk500_recv(): programmer is not responding
我能保证Board和Serial都没有选错，板子型号为: Arduino Nano w/ ATmega328, 串口为: /dev/tty.usbserial-A92D9FNR，但是还是出现问题。
截图当中，为了模拟这个问题，所以将串口选到了/dev/tty.Bluetooth-incoming-Port，所以，出现这个问题，第一就应该先检查板子型号和对应的串口名称，因为最可能是这方面出现的错误。

经过搜索，发现网上也有同样的问题：
http://forum.arduino.cc/index.php?topic=123573.0
全文如下

I had the same problem!

If you are using an Arduino Nano w/ OSX you need to install the drivers.

Download and execute it:

http://www.ftdichip.com/Drivers/VCP/MacOSX/FTDIUSBSerialDriver_v2_2_14.dmg

And you'll find this files:

    FTDIUSBSerialDriver_10_3.pkg which is specific to OSX 10.3 (Panther)
    FTDIUSBSerialDriver_10_4_10_5_10_6.pkg which is specific to OSX 10.4 (Tiger), OSX 10.5 (Leopard)
    and 10.6 (Snow Leopard).


Execute "FTDIUSBSerialDriver_10_4_10_5_10_6.pkg" if you are using OSX 10.5+ (Leopard+)

Best!

所以，到这个网址下载最新的FTDI驱动，安装好就可以使用了
http://www.ftdichip.com/Drivers/VCP/MacOSX/FTDIUSBSerialDriver_v2_2_14.dmg

2,313 total views, no views today

The post 解决Mac上无法对Arduino Nano编程的问题 appeared first on HE Qichen's Hackspace.

我们原定的目标就是通过Arduino来作为四轴飞行器的控制板，那么必然就需要用Arduino来控制四个电机的转速，其实就是多PWM输出。在去年我已经实现了单电机的输出，发现了不少问题。

首先，舵机的信号格式和我们用的电调的信号格式是相同的，一般来说，航模上的电调信号线接于接收器的三号通道上，但是，如果接在别的通道上也是能正常工作的，这也证明了他们之间信号是相同的。

但是，上次通过Arduino上的Servo库来控制电机时，发现Servo库输出的pwm宽度会超过电调接收的范围，从而导致电机无法启动。然而，通过遥控器遥控时就不存在这个问题。所以，我今天就首先对遥控器的pwm信号进行测量，然后对Arduino输出的pwm信号进行测量。然后计算出控制方式。注意：这里的pwm信号是通过Arudino上Servo库输出的pwm信号，它是脉冲宽度调制，不是Arduino默认的pwm，默认的pwm是通过占空比来模拟一个模拟量。

好了，不多说，上图。

首先，测试电池是否有能力带动两个电机同时稳定地工作，我用遥控器电路对他们进行了测试。先搭建了一个下图所示的电路，进行测试。

http://v.youku.com/v_show/id_XMjcwNzAxNzY0.html

然后就需要测量遥控器输出的脉冲宽度和Arduino输出的脉冲宽度，搭了下面这个电路。为此我还去买了能测占空比的ut10a，但是那个万用表实在不给力，根本没有办法量到数据。-_-b

这张图当中电调只是起到供电的作用，所以并没有连电机。

无奈，但是发现Arduino有pulseIn()这个函数，可以计算一个高电平或低电平持续时间，正好，把数据拿下了。

最高位：	1900us
最低位：	1100us

那么就碰到了另外一个问题，既然没有仪器来测量脉冲宽度，那如何去测量Arduino输出的PWM脉冲的宽度呢？我在万念俱灰的情况下，把两个Arduino上的数字端口连在了一起，就像下面图中的一样，看看是否能自己测量自己。

结果很出乎意料，居然得到数据了，真的很佩服Arduino写底层库的人，中断控制得如此完美:-)

可以看到，Servo库在输出0时，对应的脉冲宽度为522ms；而输出180时，对应的脉冲宽度为2373ms。远远大于遥控器输出的范围，所以导致一开始电调无法识别Arduino的pwm信号。这样经过简单的计算就可得出，电调的最低位应为56度，最高位应为133度。:-D

有了这个重要的数据，下面就可以用它来控制电机了。不过首先还是先让程序控制舵机，保证他能正常运行，呵呵。

测试通过之后，就上电机啦。通过控制板上的两个旋钮，其实就是可变电阻，来控制电机的速度。

上视频

http://v.youku.com/v_show/id_XMjcwNzA0MDAw.html

控制板特写

右边的电源模块特写，整个系统的动力电源和控制电源分为两路，控制电源由我自己做的手机电池包来提供．

电机特写，呵呵，山寨味道太浓了

最后，我测了下电机的电流，在两个电机空载，半油门的情况下，电流为4A左右。这两个电机都是经过风风雨雨的，什么坠机、落水都经历过，轴已经有点不正常了，所以也只是带大概估计一下。

下面就是测试程序

#include <Servo.h>

//Author:	HE Qichen
//Date:	2011-5-27
//Website:	http://heqichen.cn
//Email:	heqichen(a)gmail.com

#define inputPin1  A8
#define inputPin2  A9

#define motorPin1  5
#define motorPin2  6

Servo motor1;
Servo motor2;

void setup()
{
  motor1.attach(motorPin1);
  motor2.attach(motorPin2);
  motor1.write(motorSpeedTransfer(0));
  motor2.write(motorSpeedTransfer(0));
  Serial.begin(9600);
}

void loop()
{
  int input1, input2;
  int speed1, speed2;
  input1 = analogRead(inputPin1);
  input2 = analogRead(inputPin2);
  speed1 = motorSpeedTransfer(input1);
  speed2 = motorSpeedTransfer(input2);
  motor1.write(speed1);
  motor2.write(speed2);
  Serial.print("#1 value: ");
  Serial.print(speed1, DEC);
  Serial.print("    #2 value: ");
  Serial.println(speed2, DEC);

  delay(500);
}

int motorSpeedTransfer(int s)
{
  return (s/13 + 56);
}

3,255 total views, no views today

The post Arduino控制多电调控制测试 appeared first on HE Qichen's Hackspace.

这就是需要改造的部分。

先将需要改造的部分画下来，便于设计框架结构。我不是机械出身的，所以就画个大概吧。

结构图完成

在图纸上设计新的结构

根据设计切割材料

最后完成的样子，由于是临时电路，也就没固定，看上去有点像垃圾车-_-b

改造部分的特写

再来一张

这些只是机械部份，然后就是控制部份。由于舵机能够转动的角度范围到180度，而该车的转向轮仅能转动在30-40度之间。同时，自主移动机器人目标是在Arduino上面开发。所以我就一步到位，先用Arduino读取天地飞的pwm信号，然后经过转换，输出新的pwm信号给舵机，这样就不会因为卡住而损坏舵机了。

最后效果如下

http://v.youku.com/v_show/id_XMjYzOTc2NzA4.html

使用的程序非常简单，如下：

#include <Servo.h>

//Author:	HE Qichen
//Date:	2011-5-3
//Website:	http://heqichen.cn
//Email:	heqichen(a)gmail.com

Servo directionServo;

void setup()
{
  pinMode(2, INPUT);
  directionServo.attach(3);
  
}

void loop()
{
  int t, a;
  t = pulseIn(2, HIGH);
  a = map(t, 1000, 2000, 65, 115);
  directionServo.write(a);
  
  
}

1,929 total views, no views today

The post 遥控小车的改造 appeared first on HE Qichen's Hackspace.

现在重力传感器应用非常广，目前iphone等智能手机上都有重力传感器，包括笔者的一台山寨手机上都有重力传感器。

这次就是要用Android来读取重力传感器的数据。这个重力传感器模块是从淘宝购买的，模块非常简单，自己够买芯片来焊接也不成问题。根据它的datasheet，就能够知道如何使用这款重力加速度模块了。下面就进行详细的介绍

这个模块使用的芯片型号是MMA7260Q，(datasheet下载[PDF,229KB])，测试中的电路就是下面图片中的样子

控制的目标是通过重力传感器的数据来控制舵机的转动。但是发现会有少量的抖动，于是在程序中加入了一个简单的滤波器，阶数没有仔细调，但是基本上能够进行控制了。

http://v.youku.com/v_show/id_XMjYzNjIyODIw.html

下面是芯片的特写

下面是用到的代码

#include <Servo.h>

//Author:  HE Qichen
//Email:  heqichen(a)gmail.com
//Website:  http://heqichen.cn
//Date:  2011-5-2

#define FILTER_LEVEL  3

class Filter
{
  private:
    int buffer[FILTER_LEVEL];
  public:
    Filter()
    {
      int i;
      for (i=0; i<FILTER_LEVEL; ++i)
      {
        buffer[i] = 0;
      }
    }
    int filter(int value)
    {
      int i;
      int sum;
      for (i=0; i<FILTER_LEVEL-1; ++i)
      {
        buffer[i] = buffer[i+1];
      }
      buffer[FILTER_LEVEL-1] = value;
      sum = 0;
      for (i=0; i<FILTER_LEVEL; ++i)
      {
        sum += buffer[i];
      }
      return sum / FILTER_LEVEL;
    }
};

Servo testServo;
Filter xFilter, yFilter, zFilter;

void setup()
{
  Serial.begin(9600);
  testServo.attach(2);
}

void loop()
{
  int gx, gy, gz;
  gx = analogRead(A0);
  gy = analogRead(A1);
  gz = analogRead(A2);

  Serial.print("x: ");
  Serial.print(gx, DEC);
  Serial.print("  y: ");
  Serial.print(gy, DEC);
  Serial.print("  z: ");
  Serial.println(gz, DEC);

  int fgx, fgy, fgz;
  fgx = xFilter.filter(gx);
  fgy = yFilter.filter(gy);
  fgz = zFilter.filter(gz);
  Serial.print("  fx: ");
  Serial.print(fgx, DEC);
  Serial.print("  fy: ");
  Serial.print(fgy, DEC);
  Serial.print("  fz: ");
  Serial.println(fgz, DEC);

  testServo.write((fgz-100)/3);
  //delay(10);

}

1,875 total views, 3 views today

The post Arduino读取g-sensor数据 appeared first on HE Qichen's Hackspace.

这个陀螺仪使用ITG3200芯片，可以直接使用了I2C接口连接到Arduino上面。默认的地址是0x68，但是可以修改成0x69，只要将板子上的JP1连起来就可以修改。接口四个针脚的定义就像下面这张图中所画的。

是的。。你没看错，他们用红色作为地线 -_-b

舵机就是最简单的使用pwm的口就可以了。最后链接成下面这张图中的样子。

我写了一个程序，代码在下方，能够做到让陀螺仪的转动直接反应在舵机的摇臂上面。但是，这样也会遇到问题，就是当动的次数比较多的时候，舵机的角度就会越来越大，直到超过最大的范围，所以这也是陀螺仪不是很精确的地方。另外就是，在陀螺仪静止的情况下，z轴的输出不为0，始终为-1。也就是说，这个陀螺仪的零点可能是不准确的，同时，正负转动的也有可能有差别，不知道这回对将来飞控算法带来多大的影响。

最后用到的程序就是下面这段。

#include <Wire.h>
#include <Servo.h>

#define GYRO_ADDR  0x68

Servo servo;

int currentPos;

void setup()
{
  Wire.begin();
  initGyro();
  servo.attach(2);
  currentPos = 90;
  //Serial.begin(9600);
  pinMode(3, INPUT);
}

void loop()
{
  int x;
  int v;
  x = readx();
  v = ready();
  v = readz();
  currentPos = currentPos + x;

  int buttonState;
  buttonState = digitalRead(3);
  if (buttonState == HIGH)
  {

    currentPos = 90;
  }
  else
  {
    //Serial.println("LOW");
  }

  servo.write(currentPos);

}

int readx()
{
  int x;
  x = readGyro(0x1d, 0x1e);
  return x;
}

int ready()
{
  int y;
  y = readGyro(0x1f, 0x20);
  return y;
}

int readz()
{
  int z;
  z = readGyro(0x21, 0x22);
  return z;
}

char readGyro(unsigned char addrH, unsigned char addrL)
{
  char ret;
  Wire.beginTransmission(GYRO_ADDR);
  Wire.send(addrH);
  Wire.endTransmission();
  Wire.requestFrom(GYRO_ADDR, 1);
  if (Wire.available() > 0)
  {
    ret = Wire.receive();
  }
  Wire.beginTransmission(GYRO_ADDR);
  Wire.send(addrL);
  Wire.endTransmission();
  Wire.requestFrom(GYRO_ADDR, 1);
  if (Wire.available() > 0)
  {
    ret != Wire.receive()<<8;
  }

  return ret;
}

void initGyro()
{
  Wire.beginTransmission(GYRO_ADDR);
  Wire.send(0x3E);
  Wire.send(0x80);  //send a reset to the device
  Wire.endTransmission(); //end transmission

  Wire.beginTransmission(GYRO_ADDR);
  Wire.send(0x15);
  Wire.send(0x00);   //sample rate divider
  Wire.endTransmission(); //end transmission

  Wire.beginTransmission(GYRO_ADDR);
  Wire.send(0x16);
  Wire.send(0x18); // ±2000 degrees/s (default value)
  Wire.endTransmission(); //end transmission
}

程序当中Wire库就是使用I2C，具体文档可以看下面的链接。

http://arduino.cc/en/Reference/Wire

http://v.youku.com/v_show/id_XMjYzMTg2ODQ0.html

1,972 total views, no views today

The post 在Arduino上使用陀螺仪控制舵机 appeared first on HE Qichen's Hackspace.

CT1	接受pwm，控制速度
CT2	前进控制信号，高电位转动
CT3	后退控制信号，高电位转动

但是由于小车上的UNO与我的Ubuntu连接有问题，貌似只有Windows是好的，Mac OS有时也会出问题。所以最后车上改用了Mega 1280。

但是又发现一个问题，就是Arduino使用USB供电的时候很正常，然而，使用车上接出来的5V电源时，程序就会混乱，完全没有一点规律。猜测可能是由于电机转动导致整个系统的电压下降，无法提供足够的电压给Arduino的板子上。这大概也是之前uno不会发疯的原因。没办法，在小车上再接一块9V层叠式电池，作为Arduino的电源。最后终于行了。

后面程序的作用是往前走，遇到前方有物体是后退，打弯，然后继续往前，一个简单的壁障程序。没有用到速度控制。下面就是这个小车最后的样子，手机拍的，将就看吧

左侧照

右侧照

再来一张

http://v.youku.com/v_show/id_XMjYzMzY0NzA0.html

用到的程序就是下面的

//Author:	HE Qichen
//Email:	heqichen(a)gmail.com
//Website:	http://heqichen.cn
//Date:	2011-5-1

int status;

#define LEFT_SPEED   6
#define LEFT_FORWARD  7
#define LEFT_BACKWARD  8

#define RIGHT_SPEED  10
#define RIGHT_FORWARD  11
#define RIGHT_BACKWARD  12

#define ULTRASONIC_ECHO  3
#define ULTRASONIC_TRIG  4

#define NORMAL_SPEED  100
#define STOP_SPEED  0

void setup()
{
  Serial.begin(9600);
  setupMove();
  setupUltrasonic();
}

void loop()
{
  unsigned int d;
  moveForward();
  d = readDistance();
  Serial.println(d, DEC);
  if (d < 700)
  {
    moveBackward();
    delay(500);
    turnLeft();
    delay(200);
  }
}

void moveForward()
{
  analogWrite(LEFT_SPEED, NORMAL_SPEED);
  digitalWrite(LEFT_BACKWARD, LOW);
  digitalWrite(LEFT_FORWARD, HIGH);
  analogWrite(RIGHT_SPEED, NORMAL_SPEED);
  digitalWrite(RIGHT_BACKWARD, LOW);
  digitalWrite(RIGHT_FORWARD, HIGH);
}

void moveBackward()
{
  analogWrite(LEFT_SPEED, NORMAL_SPEED);
  digitalWrite(LEFT_BACKWARD, HIGH);
  digitalWrite(LEFT_FORWARD, LOW);
  analogWrite(RIGHT_SPEED, NORMAL_SPEED);
  digitalWrite(RIGHT_BACKWARD, HIGH);
  digitalWrite(RIGHT_FORWARD, LOW);
}

void turnLeft()
{
  analogWrite(LEFT_SPEED, NORMAL_SPEED);
  digitalWrite(LEFT_BACKWARD, HIGH);
  digitalWrite(LEFT_FORWARD, LOW);
  analogWrite(RIGHT_SPEED, NORMAL_SPEED);
  digitalWrite(RIGHT_BACKWARD, LOW);
  digitalWrite(RIGHT_FORWARD, HIGH);
}

void turnRight()
{
  analogWrite(LEFT_SPEED, NORMAL_SPEED);
  digitalWrite(LEFT_BACKWARD, LOW);
  digitalWrite(LEFT_FORWARD, HIGH);
  analogWrite(RIGHT_SPEED, NORMAL_SPEED);
  digitalWrite(RIGHT_BACKWARD, HIGH);
  digitalWrite(RIGHT_FORWARD, LOW);
}

void moveStop()
{
  analogWrite(LEFT_SPEED, STOP_SPEED);
  digitalWrite(LEFT_BACKWARD, LOW);
  digitalWrite(LEFT_FORWARD, LOW);
  analogWrite(RIGHT_SPEED, STOP_SPEED);
  digitalWrite(RIGHT_BACKWARD, LOW);
  digitalWrite(RIGHT_FORWARD, LOW);
}

void setupMove()
{
  pinMode(LEFT_SPEED, OUTPUT);
  pinMode(LEFT_FORWARD, OUTPUT);
  pinMode(LEFT_BACKWARD, OUTPUT);
  pinMode(RIGHT_SPEED, OUTPUT);
  pinMode(RIGHT_FORWARD, OUTPUT);
  pinMode(RIGHT_BACKWARD, OUTPUT);

  analogWrite(LEFT_SPEED, STOP_SPEED);
  digitalWrite(LEFT_FORWARD, LOW);
  digitalWrite(LEFT_BACKWARD, LOW);
  analogWrite(RIGHT_SPEED, STOP_SPEED);
  digitalWrite(RIGHT_FORWARD, LOW);
  digitalWrite(RIGHT_BACKWARD, LOW);
}

unsigned int readDistance()
{

  int duration;
  digitalWrite(ULTRASONIC_TRIG, LOW);
  delayMicroseconds(2);
  digitalWrite(ULTRASONIC_TRIG, HIGH);
  delayMicroseconds(5);
  digitalWrite(ULTRASONIC_TRIG, LOW);

  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  duration = pulseIn(ULTRASONIC_ECHO, HIGH);
  return duration;

}

void  setupUltrasonic()
{
  pinMode(ULTRASONIC_TRIG, OUTPUT);
  pinMode(ULTRASONIC_ECHO, INPUT);

  digitalWrite(ULTRASONIC_TRIG, LOW);
}

2,115 total views, 1 views today

The post 嵌入之梦-圆梦小车开发 appeared first on HE Qichen's Hackspace.

并且希望通过大家的智慧，把这个机器人做好，比如说，想在上面放一个无线摄像头；比如说，在上面放一个机械手臂；比如说，在这上面装一个超声测距模块……我将集中大家的智慧，集合到这个小车上面，^_^

http://v.youku.com/v_show/id_XMjYyMzQ4OTYw.html

如果你有想法，请告诉我

1,993 total views, no views today

The post 自主机器人项目 appeared first on HE Qichen's Hackspace.

其实这个电路十分简单，就是两个按钮接入Arduino，然后Arduino输出PWM信号到电调，电调再输出电流到电机，从而就行成了按钮控制电机的一个装置。

不过，在完成这样一个小小的系统也经历了很多挫折。

首先，舵机还是电调都是通过PWM波进行控制的，比如下面这张图当中

这个就是一般航模用的遥控器，接收机接收到射频信号后，将信号解调成PWM输出到舵机或者是电调中。所以电调和舵机都能够接收PWM信号，且信号格式是统一的。

但是，PWM信号到底是什么格式，频率多少，占空比多少，在网上查了查，却没有一个确切的数据。有个数据比就是futata的标准，pwm频率是50Hz, 脉冲宽度为920usec到2120usec，这样对应了舵机的0度到180度。

对于这个数值，我用51做了一个PWM的发生器，通过在电脑上输入角度（0到180度），然后产生一个特定的PWM波输出到舵机，就是下面这张图中的。

可是结果发现，舵机行程明显不足180度，只能勉强算是90左右，看来920usec-2120usec并不是对于舵机确切的控制数据，或者说对于除futaba以外的舵机的控制格式。
经过调试，发现要使舵机达到0度到180度的行程，PWM波的脉冲宽度要在800usec到2800usec之间。同时也有个有趣的现象。如果给舵机的信号线一个脉冲信号，宽度在800usec到2800usec之间，然后持续低电位，舵机会保持在该脉冲所对应角度不变，也就是说，PWM的频率是可以低于 50Hz的。

回到Arduino上，Arduino自带Servo的库，可以编程实现从特定的角度输出特定的PWM波。就可以是用这样的PWM信号来控制电调，从而控制电机。这里有必须介绍一下电调的特点。我们是用的电调是比较廉价的新西达电调，但是它也带模式设定的功能，可以根据不同的场合来设定电调的工作模式。设定的过程就是，PWM信号为最高时，给电调上电。具体的设定过程可以在网上查到。经过实验发现Arduino输出角度为0的PWM信号根本不会对电调有任何影响，电调完全无视这个信号的存在-_-b。经过仔细思考后发现，会不会是因为电调是用的是futaba的PWM格式，而800usec或者 Arduino最低的pwm信号对于电调来说过低，导致电调不能够辨认。

以下就是能够控制电机速度的程序代码

#include <Servo.h>

Servo myservo;
int pos = 0;
int buttonState = 0;
int lastButtonState = 0;

int currentAngle;
int MAX_ANGLE = 140;
int MIN_ANGLE = 100;
void setup()
{
 myservo.attach(9);
 pinMode(13, OUTPUT);
 pinMode(2, INPUT);
 pinMode(3, INPUT);
 currentAngle = 100;
}

void loop()
{
 buttonState = digitalRead(2);
 if (buttonState == HIGH)
 {
 digitalWrite(13, HIGH);
 if (currentAngle < MAX_ANGLE)  {  currentAngle = currentAngle + 1;  }  }  else  {  buttonState = digitalRead(3);  if (buttonState == HIGH)  {  digitalWrite(13, HIGH);  if (currentAngle > MIN_ANGLE)
 {
 currentAngle = currentAngle - 1;
 }
 }
 }
 if (buttonState == LOW)
 {
 digitalWrite(13, LOW);
 }
 myservo.write(currentAngle);
 delay(30);

}

2,841 total views, 3 views today

The post 四轴飞行器进展 appeared first on HE Qichen's Hackspace.